کلید فشاری یا سوییچ در زمان فشرده شدن، دو نقطه در مدار را به یکدیگر وصل می کند. این مثال، زمانی که کلید را فشار می دهید، LED موجود روی برد را که به پین ۱۳ متصل است، روشن می کند.

سخت افزار

  • برد آردوینو
  • کلید یا سوییچ دو وضعیتی
  • یک مقاومت ۱۰ کیلو اهمی
  • برد بورد
  • سیم برد بوردی

 

مدار:

۳عدد سیم را به برد آردوینو وصل کنید. دوسیم اول را، یعنی سیم قرمز و مشکی، به دو ردیف بلند عمودی در کناره ی برد بورد وصل کنید تا دسترسی به ۵ ولت و زمین را تأمین کنید. سومین سیم از پین دیجیتال ۲ به یکی از پایه های کلید فشاری وصل می شود. همان پایه کلید را از طریق یک مقاومت pull down به زمین وصل کنید (در اینجا ۱۰ کیلو اهمی). پایه ی دیگر کلید را به ولتاژ ۵ وصل کنید.
وقتی دکمه های فشاری باز(فشرده نشده) هستند، هیچ ارتباطی بین دو پایه کلیدهای فشاری وجود ندارد، بنابراین پین (با مقاومت pull down) به زمین وصل می شود و ما آن را به عنوان LOW می خوانیم. وقتی کلید بسته (فشرده) شود، بین دو پایه خودش ارتباطی ایجاد می کند، یعنی پین به ۵ ولت وصل می شود؛ بنابراین ما پین را به عنوان HIGH می خوانیم.
همچنین شما می توانید مدار را با یک مقاومت PullUp به صورت مخالف این شیوه ببندید. در این حالت، ورودی مدار HIGH است و زمانی که کلید فشرده می شود، به حالت LOW می رود. بنابراین، رفتار اسکچ نیز معکوس خواهد شد. به این صورت که LED به طور عادی روشن است و با فشردن کلید، خاموش می شود.
اگر شما پین ورودی/خروجی دیجیتال را از همه چیز قطع کنید، LED ممکن است بطور بی قاعده چشمک بزند. این مسئله به این دلیل است که ورودی شناور است. این بدان معناست که مقدار LOW و HIGH را به طور تصادفی بر می گرداند. به همین دلیل است که به یک مقاومت Pull-down یا pull-up در مدار نیاز است.

شماتیک:

کد:

/*
  Button

 Turns on and off a light emitting diode(LED) connected to digital
 pin 13, when pressing a pushbutton attached to pin 2.


 The circuit:
 * LED attached from pin 13 to ground
 * pushbutton attached to pin 2 from +5V
 * ۱۰K resistor attached to pin 2 from ground

 * Note: on most Arduinos there is already an LED on the board
 attached to pin 13.


 created 2005
 by DojoDave <http://www.0j0.org>
 modified 30 Aug 2011
 by Tom Igoe

 This example code is in the public domain.

 http://www.arduino.cc/en/Tutorial/Button
 */

// constants won't change. They're used here to
// set pin numbers:
const int buttonPin = 2;     // the number of the pushbutton pin
const int ledPin =  13;      // the number of the LED pin

// variables will change:
int buttonState = 0;         // variable for reading the pushbutton status

void setup() {
  // initialize the LED pin as an output:
  pinMode(ledPin, OUTPUT);
  // initialize the pushbutton pin as an input:
  pinMode(buttonPin, INPUT);
}

void loop() {
  // read the state of the pushbutton value:
  buttonState = digitalRead(buttonPin);

  // check if the pushbutton is pressed.
  // if it is, the buttonState is HIGH:
  if (buttonState == HIGH) {
    // turn LED on:
    digitalWrite(ledPin, HIGH);
  } else {
    // turn LED off:
    digitalWrite(ledPin, LOW);
  }
}

Debounce

این مثال شرح می دهد که چطور یک ورودی را (debounce) کنیم، مفهوم Debounce این است که جهت حصول اطمینان از اینکه دکمه قطعاً فشرده شده است، ورودی را در یک دوره زمانی کوتاه دو بار بررسی کنیم. بدون انجام عمل Debounce یک بار فشردن کلید می تواند در کد به صورت چندبار فشردن تشخیص داده شود. از تابع millis() جهت رهگیری زمان در موقعی که کلید فشرده شده است، استفاده می شود.

کد :

/*
 Debounce

 Each time the input pin goes from LOW to HIGH (e.g. because of a push-button
 press), the output pin is toggled from LOW to HIGH or HIGH to LOW.  There's
 a minimum delay between toggles to debounce the circuit (i.e. to ignore
 noise).

 The circuit:
 * LED attached from pin 13 to ground
 * pushbutton attached from pin 2 to +5V
 * ۱۰K resistor attached from pin 2 to ground

 * Note: On most Arduino boards, there is already an LED on the board
 connected to pin 13, so you don't need any extra components for this example.


 created 21 November 2006
 by David A. Mellis
 modified 30 Aug 2011
 by Limor Fried
 modified 28 Dec 2012
 by Mike Walters
 modified 30 Aug 2016
 by Arturo Guadalupi


 This example code is in the public domain.

 http://www.arduino.cc/en/Tutorial/Debounce
 */

// constants won't change. They're used here to
// set pin numbers:
const int buttonPin = 2;    // the number of the pushbutton pin
const int ledPin = 13;      // the number of the LED pin

// Variables will change:
int ledState = HIGH;         // the current state of the output pin
int buttonState;             // the current reading from the input pin
int lastButtonState = LOW;   // the previous reading from the input pin

// the following variables are unsigned long's because the time, measured in miliseconds,
// will quickly become a bigger number than can be stored in an int.
unsigned long lastDebounceTime = 0;  // the last time the output pin was toggled
unsigned long debounceDelay = 50;    // the debounce time; increase if the output flickers

void setup() {
  pinMode(buttonPin, INPUT);
  pinMode(ledPin, OUTPUT);

  // set initial LED state
  digitalWrite(ledPin, ledState);
}

void loop() {
  // read the state of the switch into a local variable:
  int reading = digitalRead(buttonPin);

  // check to see if you just pressed the button
  // (i.e. the input went from LOW to HIGH),  and you've waited
  // long enough since the last press to ignore any noise:

  // If the switch changed, due to noise or pressing:
  if (reading != lastButtonState) {
    // reset the debouncing timer
    lastDebounceTime = millis();
  }

  if ((millis() - lastDebounceTime) > debounceDelay) {
    // whatever the reading is at, it's been there for longer
    // than the debounce delay, so take it as the actual current state:

    // if the button state has changed:
    if (reading != buttonState) {
      buttonState = reading;

      // only toggle the LED if the new button state is HIGH
      if (buttonState == HIGH) {
        ledState = !ledState;
      }
    }
  }

  // set the LED:
  digitalWrite(ledPin, ledState);

  // save the reading.  Next time through the loop,
  // it'll be the lastButtonState:
  lastButtonState = reading;
}

نویسنده: گروه IRSE

نوشته آموزش گام به گام آردوینو (بخش هفتم: کلید Button) اولین بار در وب سایت تخصصی برق و الکترونیک پدیدار شد.